Kategorie: Datenbankzugriffe
Frage: Wie kann ich detaillierte Informationen über verwendete Datenbanktabellen bekommen?
Manchmal ist es notwendig, detaillierte Informationen über eine in ASP-Skripten verwendete
Datenbanktabelle zu bekommen (z.B.: ob Bookmarks gesetzt werden können, wie Daten,
die während der eigenen oder anderer Transaktionen eingefügt werden, angezeigt werden,
...)

Dies kann man mit wenigen Zeilen Quellcode über die Properties-Collection des Recordset-Objekts
ermitteln. Um eine bessere Übersicht zu bekommen, wird die Ausgabe in diesem Beispiel in eine
Tabelle geschrieben.

[listproperties.asp]
<%
' --- Instantiieren eines Connnection-Objekts
Set objConn = Server.CreateObject("ADODB.Connection")
    ' --- Öffnen der Datenbank
    objConn.Open "<DSN>", "<UID>", "<PWD>"

' --- Instantiieren eines Recordset-Objekts
Set objRS = Server.CreateObject("ADODB.Recordset")
    ' --- Öffnen der Tabelle
    objRS.Open "<tabelle>", objConn, 3, 3

    Response.Write "<table border=""1"" width=""100%"">" & vbCrLf
    
        ' --- Ausgabe der Überschrift
    Response.Write "<tr>" & vbCrLf
    Response.Write "<td><b>Eigenschaft</b></td>" & vbCrLf
    Response.Write "<td><b>Wert</b></td>" & vbCrlf
    Response.Write "</tr>" & vbCrLf
    
    ' --- Durchlaufen der einzelnen Werte der Properties-Collection
    For Each Property in objRS.Properties
    
        ' --- Ausgabe des Namens der Eigenschaft und des Wertes
        Response.Write "<tr>" & vbCrLf
        Response.Write "<td>" & Property.Name & "</td>" & vbCrLf
        Response.Write "<td>" & Property.Value & "</td>" & vbCrlf
        Response.Write "</tr>" & vbCrLf
    
    Next

    Response.Write "</table>" & vbCrLf

    ' --- Schliessen der Datenbank
    objRS.Close
' --- Zerstören des Connection-Objekts
Set objRS = Nothing
    
    ' --- Schliessen der Datenbank
    objConn.Close
' --- Zerstören des Connection-Objekts
Set objConn = Nothing
%>
Copyright 2000 - 2021 by Stefan Falz Webconsulting