| Frage: Wie kann ich detaillierte Informationen über eine verwendete Datenbank bekommen? |
Manchmal ist es notwendig, detaillierte Informationen über eine in ASP-Skripten verwendete
Datenbank zu bekommen (z.B.: die Versionsnummer, ob GROUP BY Klauseln unterstützt werden,
wieviele Spalten und/oder Tabellen in einer Abfrage verwendet werden dürfen, ...)
Dies kann man mit wenigen Zeilen Quellcode über die Properties-Collection des Connection-Objekts
ermitteln. Um eine bessere Übersicht zu bekommen, wird die Ausgabe in diesem Beispiel in eine
Tabelle geschrieben.
[listproperties.asp]
<%
' --- Instantiieren eines Connnection-Objekts
Set objConn = Server.CreateObject("ADODB.Connection")
' --- Öffnen der Datenbank
objConn.Open "<DSN>", "<UID>", "<PWD>"
Response.Write "<table border=""1"" width=""100%"">" & vbCrLf
' --- Ausgabe der Überschrift
Response.Write "<tr>" & vbCrLf
Response.Write "<td><b>Eigenschaft</b></td>" & vbCrLf
Response.Write "<td><b>Wert</b></td>" & vbCrlf
Response.Write "</tr>" & vbCrLf
' --- Durchlaufen der einzelnen Werte der Properties-Collection
For Each Property in objConn.Properties
' --- Ausgabe des Namens der Eigenschaft und des Wertes
Response.Write "<tr>" & vbCrLf
Response.Write "<td>" & Property.Name & "</td>" & vbCrLf
Response.Write "<td>" & Property.Value & "</td>" & vbCrlf
Response.Write "</tr>" & vbCrLf
Next
Response.Write "</table>" & vbCrLf
' --- Schliessen der Datenbank
objConn.Close
' --- Zerstören des Connection-Objekts
Set objConn = Nothing
%>
In diesem Beispiel wird keine Tabelle verwendet, um die Daten auszugeben. Dies soll Ihnen
lediglich zeigen, wie einfach man diese Informationen abrufen kann.
[listproperties.asp]
<%
' --- Instantiieren eines Connnection-Objekts
Set objConn = Server.CreateObject("ADODB.Connection")
' --- Öffnen der Datenbank
objConn.Open "<DSN>", "<UID>", "<PWD>"
' --- Durchlaufen der einzelnen Werte der Properties-Collection
For Each Property in objConn.Properties
' --- Ausgabe des Namens der Eigenschaft und des Wertes
Response.Write Property.Name & " - " & Property.Value & "<br>" & vbCrlf
Next
' --- Schliessen der Datenbank
objConn.Close
' --- Zerstören des Connection-Objekts
Set objConn = Nothing
%>
|
 |
|