Kategorie: Mail versenden
Frage: Wie versende ich Mail mit CDOSYS inkl. SMTP Authentifizierung?
Nachfolgend ein Beispiel zum Versenden einer EMail mit CDOSYS von Microsoft.
Bezugsquelle: In der Windows 2000 Installation integriert (optional).
CDOSYS ist der Nachfolger von CDONTs, allerdings um einiges leistungsfähiger.
So ist es beispielweise möglich, Attachments von anderen Server durch Angabe
der URL zu laden (http://www.einedomain.de/verzeichnis/datei.ext).

[cdosys.asp]
<!--METADATA TYPE="TypeLib" UUID="{CD000000-8B95-11D1-82DB-00C04FB1625D}" NAME="CDO for Windows 2000 Type Library" -->
<!--METADATA TYPE="TypeLib" UUID="{00000205-0000-0010-8000-00AA006D2EA4}" NAME="Microsoft ActiveX Data Objects 2.5 Library" -->
<%
Dim Mailer
Set Mailer = Server.CreateObject( "CDO.Message" )

Dim Configuration
Set Configuration = Server.CreateObject( "CDO.Configuration" )

Dim Fields
Set Fields = Configuration.Fields

    With Fields
      .Item( cdoSendUsingMethod )      = cdoSendUsingPort
      .Item( cdoSMTPServer )              = "mail.meinedomain.tld"
      .Item( cdoSMTPServerPort )        = 25
      .Item( cdoSMTPConnectionTimeout ) = 10
      .Item( cdoSMTPAuthenticate )     = cdoBasic
      .Item( cdoSendUserName )         = "info@meinedomain.tld"
      .Item( cdoSendPassword )          = "password"
      .Item( cdoURLGetLatestVersion ) = True
      .Update
    End With

    Set Mailer.Configuration = Configuration

    Mailer.Sender    = """Der Absender"" <absender@meinedomain.tld>"
    Mailer.To           = """Der Empfaenger"" <empfaenger@meinedomain.tld>"
    Mailer.Subject    = "Testmail"
    Mailer.TextBody = "Testmail TextBody"
    Mailer.Send

Set Mailer= Nothing
%>


Copyright 2000 - 2020 by Stefan Falz Webconsulting