Kategorien:
Suchbegriffe:
Suchfelder:
Suche starten
Neue Beiträge / Top 7
Alle Artikel / Liste
Bücher zu ASP/ASP.Net
Startseite / Hilfe
Fragen zu ASP/ASP.NET
Datenschutzrichtlinen
Impressum / Kontakt
Das ASP.Net Codebook. Die unentbehrliche Referenz für alle ASP.Net-Entwickler [Autoren: Stefan Falz, Karsten Samaschke]
Active Server Pages-FAQ
Active Server Pages - FAQ (v. 1.50) © 2000 - 2024 by Stefan Falz Webconsulting

GetFile! Dynamischer Dateiupload im Browser

Mail versenden Zurück Druckversion Stefan Falz 22.04.2002
Frage: Wie versende ich eine EMail mit ASPMail?
Nachfolgend ein Beispiel zum Versenden einer EMail mit ASPMail von ServerObjects.
Bezugsquelle: http://www.serverobjects.com unter der Rubrik Produkte

[aspmail.asp]
<%
Set Mailer = Server.CreateObject("SMTPsvg.Mailer")

    ' --- Da ASPMail standardmässig 7 Bit Ascii verwendet, werden
    ' --- Umlaute normalerweise nicht korrekt angezeigt. Um dies
    ' --- zu umgehen, wird CharSet auf 2 gestellt.
    Mailer.CharSet = 2

    ' --- Absender und Mailserverangaben zuweisen
    Mailer.Organization = "Ihre Firma"
    Mailer.FromName = "Ihr Firmenname"
    Mailer.FromAddress = "info@ihrefirma.de"
    Mailer.RemoteHost = "mail.server.de"

    ' --- Empfänger initialisieren (muss bei mehrfachem Aufruf
    ' --- in Schleifen auf jeden Fall gemacht werden)
    Mailer.ClearAllRecipients

    ' --- Empfänger hinzufügen
    Mailer.AddRecipient "Irgendein Empfänger", "empfaenger@irgendeinedomain.tld"

    ' --- Kopie-Empfänger (CC) hinzufügen
    Mailer.AddCC "Irgendein Kopie Empfänger", "kopieempfaenger@irgendeinedomain.tld"

    ' --- Blindkopie-Empfänger (BCC) hinzufügen
    Mailer.AddBCC "Irgendein Blindkopie Empfänger", "blindkopieempfaenger@irgendeinedomain.tld"

    Mailer.Subject = "Betreff"

    ' --- Den eigentlichen Mailtext initialisieren (muss bei mehrfachem
    ' --- Aufruf in Schleifen auf jeden Fall gemacht werden)
    Mailer.ClearBodyText
    Mailer.BodyText = "Text der Mail"

    ' --- Attachment anhängen (wenn benötigt)
    Mailer.AddAttachment Server.MapPath("./attachments/anhang.txt")

    ' --- Mit diesem Aufruf wird die Mail versendet. Der Rückgabewert True
    ' --- besagt, die Mail wurde versendet. Bei False ist ein Fehler (kann mit
    ' --- Mailer.Response ausgelesen werden) aufgetreten.
    If Mailer.SendMail Then
        SendMail = True
        m_errortext = "Die eMail wurde erfolgreich versendet."
        Else
            SendMail = False
            m_errortext = Mailer.Response
    End if

Set Mailer = Nothing
%>



Um mehrere EMails zu versenden, genügt es, lediglich die zu ändernden Informationen
auszutauschen (bei einem Newsletter normalerweise nur dern Name und die EMailadresse
des Empfängers) und wiederum die Methode SendMail aufzurufen. Das Objekt selbst muss
nicht wieder mit Set Mailer = Server.CreateObject("SMTPsvg.Mailer") neu erstellt werden.



[aspmailloop.asp]
<%

' --- Hier wird z.B. eine Abfrage aus einer Datenbank gestartet,
' --- um die EMailempfänger zu ermitteln.
...

Set Mailer = Server.CreateObject("SMTPsvg.Mailer")

    ' --- Da ASPMail standardmässig 7 Bit Ascii verwendet, werden
    ' --- Umlaute normalerweise nicht korrekt angezeigt. Um dies
    ' --- zu umgehen, wird CharSet auf 2 gestellt.
    Mailer.CharSet = 2

    ' --- Absender und Mailserverangaben zuweisen
    Mailer.Organization = "Ihre Firma"
    Mailer.FromName = "Ihr Firmenname"
    Mailer.FromAddress = "info@ihrefirma.de"
    Mailer.RemoteHost = "mail.server.de"

    Mailer.Subject = "Betreff"

    ' --- Den eigentlichen Mailtext initialisieren (muss bei mehrfachem
    ' --- Aufruf in Schleifen auf jeden Fall gemacht werden)
    Mailer.ClearBodyText
    Mailer.BodyText = "Mailtext"

    Do While Not objRS.EOF

        ' --- Empfänger initialisieren (muss bei mehrfachem Aufruf
        ' --- in Schleifen auf jeden Fall gemacht werden)
        Mailer.ClearAllRecipients

        ' --- Empfänger hinzufügen
        Mailer.AddRecipient objRS.Fields("user_name"), objRS.Fields("user_email")

        ' --- Mit diesem Aufruf wird die Mail versendet. Der Rückgabewert True
        ' --- besagt, die Mail wurde versendet. Bei False ist ein Fehler (kann mit
        ' --- Mailer.Response ausgelesen werden) aufgetreten.
        If Mailer.SendMail Then
            SendMail = True
            m_errortext = "Die eMail wurde erfolgreich versendet."
            Else
                SendMail = False
                m_errortext = Mailer.Response
        End if

        objRS.MoveNext
    Loop

    objRS.Close
Set objRS = Nothing

Set Mailer = Nothing
%>
Sehr gut
1 2 3 4 5 6
Ungenügend
Zurück | Bisherige Aufrufe: 52544 | Bisherige Bewertungen: 110 | Durchschnitt: 1,72
Stefan Falz Webconsulting